Hierba tras el cristal — 14 of 16

Chapter 2 - El jugador

[--------------------------------------------------

Tratamiento del fuselaje que atrapa

a Layna.

--------------------------------------------------]

[Lo primero es traerlo a la cabina -hacerlo

relevante- en cuanto se intenta cualquier

cosa que no sea mirar]

Instead of doing anything except pointing or waking or singing or thinking or looking or examining or taking inventory or rubbing or metacommanding or topiccommanding or gasking or asking or telling or touching when the seccion is not in cabina and the current action is not asking something about (this is the descubre fuselaje rule):

relatar fragmento en Table of Descubriendo el Fuselaje;

say "[italic type]Está bien. Sólo intento ser útil[roman type].";

now seccion is in cabina.

The descubre fuselaje rule is listed first in the instead rules.

[HISTORIA: El fragmento de descubrir el fuselaje]

Table of Descubriendo el Fuselaje

[Cualquier movimiento quedará de todas formas impedido en presencia del fuselaje]

Instead of going or exiting or entering or turning or jumping when the seccion is in cabina:

say "Es imposible moverse de aquí, incluso girarme, mientras me tenga apresada esta jodida [j]cosa[x]...";

if Itk is visible, say "[line break] El [j]mono[x] salta animando ante mis intentos de moverme y grita: 'Soak! Itk! Oook!'.".

[Suprimimos el TODO de una manera un poco extravagante]

Todo is a decorado activo in cabina.

Instead of doing anything to Todo (this is the todo rule), say "Prefiero considerar las cosas de una en una. O aplastarlas de una en una. O incluso reventarlas de una en una. Pero de una en una.".

The todo rule is listed first in the instead rules.

[VERBO APARTAR: simplemente lo ponemos como sinónimo de golpear, es igual de útil]

Understand "apartar [a thing]" or "aparta [a thing]" as attacking.

[VERBO DOBLAR: simplemente lo ponemos como sinónimo de golpear, es igual de útil]

Understand "doblar [a thing]" or "dobla [a thing]" as attacking.

[ACCION AYUDA: para mosquear]

Helping is an action applying to nothing.

Understand "ayuda" as helping.

Carry out of helping:

say "[bold type]** No hay ayuda integrada en esta ficción interactiva. Revisa la documentación adjunta, sigue probando y lee con cuidado, prueba a usar las palabra resaltadas **[roman type]";

say line break.

[ACCIÓN RETORCER: la hacemos igual que golpear]

Instead of squeezing something:

try attacking the noun.

[ACCIÓN MOVER LAS PIERNAS: aclarar que no pueden salir]

Instead of pulling or pushing las piernas:

say "Intento mover las [j]piernas[x], pero siguen atrapadas.";

if Itk is visible, say "[line break]El [j]mono[x], al ver mis esfuerzos, golpea el [j]fuselaje[x] y dice: 'Oo lami lami noop'.".

[ACCION MOVER PARTES DEL CUERPO: poner frase graciosilla]

Instead of pulling or pushing a parte del cuerpo:

say "Muevo [el noun], lo que no me ayuda mucho.";

if Itk is visible, say "[line break]El [j]mono[x] repite exactamente los mismos movimientos que yo y parece muy divertido... ven para acá monito y verás...".

[ACCIÓN TIRAR: de nuevo como golpear]

Instead of pulling or pushing something:

try attacking the noun;

if Itk is visible, say "[line break]El [j]mono[x] también lo intenta. Fracasa y se vuelve. Sonríe y dice: 'Oo lami noea Itk oo.'.".

[Caso especial para el extintor]

Instead of pulling or pushing the extintor:

say "Intento mover el extintor, tal vez haya algo de los controles que pueda ser... pero nada... no hay manera.";

now the extintor is tocado;

if Itk is visible, say "[line break]El [j]mono[x] también lo intenta. Fracasa y se vuelve. Sonríe y dice: 'Oo lami noea Itk oo.'.".

[ACCIÓN PENSAR: decir algo nuevo...]

Instead of thinking:

say "Bah... para eso ya encontraré mejor momento.".

[ACCIÓN CANTAR: alguna broma]

Singing is an action applying to nothing.

Understand "cantar" or "canta" as singing.

Instead of singing:

say "Llevo instalado un complemento auditivo de alta sensibilidad, así como un extra al neo-cortex para análisis de altas y bajas frecuencias... pero el extra de sensibilidad musical era demasiado caro, así que nada de cantar.";

if Itk is visible, say "El mono parecía muy interesado. ¿Querrá que cante?".

[ACCIÓN SEÑALAR: una completamente nueva]

Pointing is an action applying to one thing.

Selfpointing is an action applying to nothing.

Understand "señalar" or "señala" or "señalo" or "senala" or "senalar"or "senalo" as "[point]".

Understand "[point] [a visible thing]" or "[point] a [a visible thing]" as pointing.

Understand "[point] a mi" or "señalarme" or "señalame" or "me señalo" as selfpointing.

Carry out of selfpointing:

say "Me señalo.";

say line break;

if Itk is visible

begin;

say "El [j]mono[x] señala y dice: 'Itk. Lami lami oo.'";

otherwise;

say "Lo que no es más que una redomada estupidez, todo sea dicho.";

end if.

Carry out of pointing:

if Itk is visible

begin;

say "Señalo [al noun] con diversos gestos y el extraño [j]mono[x] mira con atención, como si quisiese interpretar mis gestos.";

otherwise;

say "Hago gestos señalando [al noun], aunque no hay nadie para verlo así que no sé que fundida cosa se me ha pasado por la cabeza.";

end if.

[ACCION MOSTRAR: la cambiamos por señalar]

Before of showing a thing to Itk when the noun is not carried:

try pointing the noun;

stop the action.

Instead of showing a thing to Itk:

say "El [j]mono[x] [lo noun] coge con avidez, pero [lo noun] deja caer en cuanto ve que no es comestible.";

move the noun to cabina.

[ACCION BUSCAR: la cambiamos por examinar]

Instead of searching:

try examining.

[ACCIÓN BESAR: la cambiamos por atacar]

Instead of kissing:

try attacking.

[ACCIÓN ATACAR: algunos detalles]

Instead of attacking yourself:

say "No tiene sentido ahora mismo, la verdad.".

Instead of attacking:

say "Dan ganas de... bueno, da igual, sería inútil.".

[ACCIÓN OLER: por lo menos poner un texto graciosillo]

Instead of smelling:

say "Uhm... no huelo nada extraño... ¡oh, no! No huelo una fundida cosa. El olfato también debe haber dejado de funcionar.";

if Itk is visible, say "[line break]El [j]mono[x] hace gesto de oler... y parece que algo no huele muy bien, espero no ser yo...".

[ACCION REGISTRAR: la redirigimos a examinar]

Instead of searching something:

try examining the noun.

[ACCIÓN ESCUCHAR: lo mismo]

Instead of listening:

say "Aumento lo que puedo mi sensibilidad auditiva... y no escucho nada de interés.";

if Itk is visible, say "El [j]mono[x] mira mis orejas artificiales con curiosidad.".

[ACCIÓN SABOREAR: lo mismo]

Instead of tasting a parte del cuerpo:

say "Soy cara de narices, incluso la nariz es cara de narices, pero no soy comestible. No ser comestible da muchas ventajas en un trabajo como el mío.".

Instead of tasting:

say "Ya comeré cuando sea imprescindible.".

[ACCIÓN TOCAR: un poco más...]

Instead of touching a limpio thing:

say "No parece muy diferente de como suele ser.";

if Itk is visible, say "El [j]mono[x] mira con interés lo que hago, y luego da unos golpecitos él mismo.".

Instead of touching a sucio thing:

say "No parece muy... ¡mald... ya me he puesto los dedos negros otra vez.";

now the noun is tocado;

if Itk is visible, say "El [j]mono[x] mira con interés lo que hago, y luego da unos golpecitos él mismo.".

Understand "acaricia [a thing]" as touching.

Instead of touching a parte del cuerpo:

say "No estamos ahora mismo con ganas de jueguecitos guarros. Eso sí en cuanto pueda comprar otro RZ...".

Instead of touching yourself:

say "No estamos ahora mismo con ganas de jueguecitos guarros. Eso sí en cuanto pueda comprar otro RZ...".

[ACCION ABRIR: por poner cosas de Itk]

Instead of opening when Itk is visible:

say "Ahora no puedo abrirlo.";

say "El [j]mono[x] se ríe a carcajadas de mi intento. Cada vez me cae mejor este animalejo, en cuanto le ponga las manos encima haré varios animalejos con él: el animalejo cabeza, el animalejo brazo derecho...".

[ACCION CERRAR: por poner cosas de Itk]

Instead of closing when Itk is visible:

say "Ahora no puedo cerrarlo.";

say "El [j]mono[x] se ríe a carcajadas de mi intento. Cada vez me cae mejor este animalejo, en cuanto le ponga las manos encima haré varios animalejos con él: el animalejo cabeza, el animalejo brazo derecho...".

[ACCION CORTAR: la frase original es horrible para el caso]

Instead of cutting:

say "Si tuviese una segeta láser, o al menos un trazador de alta potencia entonces tal vez.".

[ACCIÓN DESPERTAR: la frase original no me gusta... nunca me gusta, ¿no?]

Instead of waking up for the first time:

relatar fragmento en Table of primer intento de despertar.

Instead of waking up:

say "Evidentemente no estoy dormida. Yo no sueño con estar en fundidos planetas perdidos en mitad del maldito espacio sin posibilidades de moverme. Para eso instalé el Sweet & Golden Dreamer hace dos añor en el neo-cortex auxiliar.".

[HISTORIA: intentar despertarse la primera vz]

Table of primer intento de despertar

[ACCION COGER EXTINTOR: por darle algo más de vidilla]

Instead of taking extintor:

say "Tiro de él a ver si consigo extraerlo, pero solo consigo sentirme aún más patética. ¡Maldita sea!";

now the extintor is tocado.

Understand "saluda" or "saludar" or "sonrie" or "sonreir" as waving hands.

Saluding is an action applying to one thing.

Understand "saluda [someone]" or "saludar [someone]" or "sonrie [someone]" or "sonreir [someone]" as saluding.

[ACCIÓN SALUDAR: por poner cosillas de Itk]

Instead of waving or waving hands or saluding when Itk is visible:

say "Saludo al [j]mono[x].";

say "El mono responde con algo como: 'Oo lami lami nuk nuk'.".

Instead of waving or waving hands:

say "No me apetece saludas estúpidamente. Me apetece romper cosas.".

[ACCION DE HABLAR COMO UN LOCO Y GRITAR: a ver si funciona correctamente]

Screaming is an action applying to nothing.

Understand "gritar" or "grita" as screaming.

Carry out of screaming:

say "¡FUNDIDA MIERDA DE [j]BOTE[x], DE [j]NANOS[x] Y LA PUTA MADRE DE LA REINA DE LOS XENOMORFOS!";

say line break;

say "¡Joder, joder y más joder!".

Mading is an action applying to nothing.

Understand "habla" as mading.

Carry out of mading:

if Itk is visible

begin;

say "Intento comunicarme con esta cosa... 'Oop Pouk Xzzxy'... bah! me mira como si fuese idiota.[line break][line break]Como si yo fuese idiota, él [j]mono[x] este es evidentemente idiota de nacimiento.";

otherwise;

say "Mala cosa si ya empiezo a pensar en hablar sola, ya tengo bastante con hablar con charraros de soporte de información enloquecidos.";

end if.

Instead of telling yourself about something, try asking yourself about it.

Instead of answering yourself that something, try asking yourself about it.

Instead of asking yourself for something, try asking yourself about it.

Instead of asking yourself about something, try mading.

[PARTE DEL CUERPO: Voz]

La voz is a person in cabina. La voz is an scenery.

Understand "informacion" or "lm-235" or "lm" as voz.

The description of the voz is "Estaría bien que el [j]LM-235[x] tuviese un cuerpo que pudiese recibir palizas, palizas contundentes, pero lamentablemente está dentro de mi propia cabeza, y la verdad, ya tuve bastante de masoquismo por un par de vidas, al menos.".

[Reglas especiales de tratamiento con la voz]

[ACCION: G. Asking, o sea preguntar nada]

Gasking is an action applying to one thing.

Understand the commands "conversa" as "habla".

Understand "habla a/con [someone]" as gasking.

[Vamos a irlo cambiando aleatoriamente en una tabla de respuestas]

Carry out of gasking:

if the noun is the voz

begin;

choose a random row in the Table of Gasking;

relatar fragmento en respuesta entry;

otherwise;

try mading;

end if.

[TABLA DE GASKING POR INTENTOS]

Table of Gasking