Hierba tras el cristal — 16 of 16
Johan Paz
Chapter 4 - Los PNJs
Section 1 - El PNJ Itk
[Sólo hay un PNJ, el quinto objeto, ¿quién
no hablaría de la quintaesencia de la molestia?]
[QUINTO OBJETO: ITK
Itk es el único PNJ de la aventura y representa
la única posibilidad de Layna de salir de esta tan
desagradable situación. Claro que nadie habla
'itkiano', ni Itk, evidentemente...
]
Itk is a man. The description of Itk is "Se trata de alguna clase de... [j]mono[x], uno que nunca has visto, boca y nariz negra y demasiado pequeñas, orejas inmensas, ojos marrones gigantescos y todo lo demás... bueno... cubierto de largos [j]pelos[x] de un color amarillento tendiendo a... feo.".
Itk can be aparecido. Itk is not aparecido.
Understand "mono" or "lemur" or "engendro" or "pequeño" or "pequeñajo" or "amarillento" or "amarillo" or "delgado" or "delgaducho" as Itk.
The printed name of Itk is a "lemur delgaducho y amarillento". The keyword of Itk is "lemur".
[Itk aparecerá sí o sí treinta turnos tras el comienzo del juego, incluso si no se ha limpiado el extintor]
When play begins, Itk appears in 30 turns from now.
[DECORADO ACTIVO: Pelos]
Los pelos is a decorado activo and a part of Itk. The pelos are plural-named.
The description of the pelos is "Largos y enmarrañados los pelos de este [j]mono[x] más que cubrirlo sirven para aumentar la sensación de que se trata de una criatura flacucha y lamentable.".
[Regla para aparecer]
At the time when Itk appears:
if Itk is not aparecido
begin;
move Itk to cabina;
relatar fragmento en Table of Itk aparece;
now Itk is aparecido;
end if.
Table of Itk aparece
| frase |
| "Un extraño ser entra por el agujero del parabrisas." |
| "Es alguna clase de [j]mono[x] flacucho y peludo que se sienta sobre los destrozados controles y me mira con curiosidad." |
| "[italic type]Sin lugar a dudas se trata de alguna clase de lemur, un insectívoro gigante. Pero no es de una especie que reconozca.[roman type]" |
| "Debí comprar el modelo caro." |
| "[italic type]¿Modelo caro? ¿De qué?[roman type]" |
| "De tí, evidentemente." |
[Regla para reaparecer]
At the time when Itk reaparece:
if Itk is not visible
begin;
move Itk to cabina;
say "El [j]mono[x] se asoma con cautela entre la hierba. Se tranquiliza rápidamente, entra y se vuelve a sentar sobre los [j]controles[x] como si nada hubiese pasado...";
end if.
[Itk no se deja tocar]
Instead of taking or attacking or rubbing Itk:
say "Intento coger al mono desgarbado, pero parece asustarse, salta por el agujero del parabrisas y desaparece entre la hierba...";
play Sound of Lemur in midground;
remove Itk from play;
Itk reaparece in four turns from now.
Instead of giving something to Itk:
say "Itk coge [el noun] con interés, [lo noun] muerde y [lo noun] deja caer con cara de decepción.";
move the noun to cabina.
[Todas las acciones en presencia de Itk, no queda otra pues no hay forma de traducir
el contenido de 'the current action']
[Primero lo auténticamente importante]
After pointing the nanos when Itk is visible:
if the nanos is reflexed
begin;
say "El mono coge el cilindro del [j]compartimiento[x] de atrás, lo revisa, lo muerde y lo deja caer con cara de frustración.[line break]Casi me acierta en la pierna con el [j]cilindro[x] al dejarlo caer al suelo. ¡Fundido mono!. Espero que no se haya roto.";
now the nanos is not reflexed;
end if.
[Y luego el adorno, lamentablemente no funciona con casi nada si hay in Instead of...]
After removing something from something when Itk is visible:
say "El mono mira con atención como muevo [el noun]".
After inserting something into something when Itk is visible:
say "El mono mira [el noun] y cómo lo inserto en [el second noun], tras lo cual dice: 'Oo Itk maoi.".
After putting something on something when Itk is visible:
say "El mono mira [el noun] y cómo [lo noun] inserto en [el second noun], tras lo cual dice: 'Oo Itk olu?.".
After examining Itk when Itk is visible:
say "El mono te sonríe con dientes amarillos y dice: 'Itk.'.".
After examining yourself when Itk is visible:
say "El mono también me está mirando con interés. Me entran ganas locas de partirle la cara y decirle 'ni se te ocurra pensarlo, flacucho', pero no es más que una tontería.".
After examining something when Itk is visible:
say "El mono también observa [el noun] con interés[if a random chance of 20 in 100 succeeds] , incluso [lo noun] señala con su mano escuálida[end if].".
After dropping something when Itk is visible:
say "El mono coge [el noun] casi antes de que llegue[n noun] a tocar el fondo de la cabina, [lo noun] mira con interés, [lo noun] muerde y, finalmente, [lo noun] deja caer con cara de asco.".
After taking inventory when Itk is visible:
say "El mono me imita y parece revisar también si lleva algo consigo.".
Instead of asking Itk about anything:
play Sound of Lemur in midground;
say "El mono me oye y al final dice: 'Oo lami nuk nuk Itk.' Que debe ser su forma de decir 'no he entendido una fundida cosa de lo que has dicho'.".
Instead of telling Itk about something, try asking Itk about it.
Instead of answering Itk that something, try asking Itk about it.
Instead of asking Itk for something, try asking Itk about it.
Instead of asking Itk to try doing something:
say "El [j]mono[x] me oye y al final dice: 'Oo lami nuk nuk Itk.' Que debe ser su forma de decir 'no he entendido una fundida cosa de lo que has dicho'.".
After waiting when Itk is visible:
say "El mono pone cara de aburrido.".